Druckereinstellungen als Admin aufrufen

Ab und zu kann es notwendig sein, die Druckereinstellungen mit Admin-Rechten aufzurufen. Man sollte allerdings zum täglichen Arbeiten nicht als Admin angemeldet sein… 😉
Also, was tun, um die Druckereinstellungen mit Administratorenrechten aufzurufen?

Der Rechtsklick auf den Drucker zeigt im Kontextmenü keinen entsprechenden Eintrag, wie man Ihn z.B. aus dem Dateiexplorer kennt.
Also gehen wir einen kleinen Umweg, den man später ggf. auch innerhalb einer Batch-Datei nutzen kann.

Im Startmenü als Suche cmd eingeben und dann die gefundene Eingabeaufforderung (cmd.exe) per Rechtklick aus dem Kontextmenü „Als Administrator ausführen“.
Am Promt der Eingabeaufforderung können dann folgende Aufrufe genutzt werden:

:: Liste aller am System vorhandenen Drucker
reg query "HKCU\Software\Microsoft\Windows NT\CurrentVersion\Devices"

:: Aufruf der Druckereinstellungen eines bestimmten Druckers
:: Dabei DRUCKERNAME durch den eigenen Druckernamen ersetzen!
rundll32.exe printui.dll,PrintUIEntry /e /n DRUCKERNAME

Welche Parameter es hier noch zur Verwendung gibt, hat z.B. Hannes Schurig auf seiner Seite gelistet, dazu noch einige weitere Infos und Beispiele…

UPDATE

Aufgrund der Rückfrage von Thomas (Siehe Kommentare), habe ich mich noch einmal an ein komplettes Script gesetzt. Dieses bietet nun eine Liste der vorhandenen Drucker zur Wahl und öffnet die Druckerverwaltung zum gewählten Drucker.
Das Script sollte als Administrator gestartet werden, damit auch alle Aufrufe funktionieren. Ggf. legt man sich eine entsprechende Verknüpfung zum Script an, die direkt als Administrator ausgeführt wird (Eigenschaften -> Verknüpfung -> Erweitert -> ‚Als Administrator ausführen‘).

@ECHO OFF

:: Liste aller am System vorhandenen Drucker zur Auswahl
:: Oeffnen der entsprechenden Druckerverwaltung entsprechend der Auswahl
:: Scripthilfe von Rubberman via Administrator.de

setlocal
set "regVar=HKCU\Software\Microsoft\Windows NT\CurrentVersion\Devices"
set count=0
for /f "tokens=*" %%a in ('Reg Query "%regVar%" /S^| findstr /v "HKEY"') do (
    set /a count+=1
    set "line=%%a"
    setlocal EnableDelayedExpansion
    for /f "delims=;" %%b in ("!line:REG_SZ=;!") do (
        endlocal
        call :setvar %%b
    )
  )
)

setlocal EnableDelayedExpansion
for /l %%i in (1 1 %count%) do (
	echo %%i. !key[%%i]!
)
echo.

set /p drucker=Bitte die Nr. des Druckers angeben: 

:: An dieser Stelle koennte bzw. sollte noch die Eingabe validiert werden,
:: bevor es zum tatsaechlichen Aufruf kommt. Fuer den Eigengebrauch aber 
:: sicherlich auch so ok. ;)

echo.
echo AUFRUF: rundll32.exe printui.dll,PrintUIEntry /e /n "!key[%drucker%]!"
echo.

call rundll32.exe printui.dll,PrintUIEntry /e /n "!key[%drucker%]!"

pause
exit /b


:setvar
set "key[%count%]=%*"
exit /b

Scripthilfe

3 Antworten auf „Druckereinstellungen als Admin aufrufen“

    1. Hallo Thomas.
      Wenn ich die Frage richtig verstehe, den obigen Quellcode in eine Textdatei kopieren, hier also die Zeile 6 mit dem entsprechenden Druckernamen.
      Die Textdatei z.B. als Druckereinstellung.cmd (Name ist frei wählbar, nur die Dateiendung muss bleiben) speichern. Diese Datei dann per Rechtsklick „Als Administrator ausführen“.
      Das sollte es sein…

      Grüße, Jörg

Schreibe einen Kommentar

Deine E-Mail-Adresse wird nicht veröffentlicht. Erforderliche Felder sind mit * markiert.